1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# freeqsay recipes. Everything here assumes nim on PATH.

# Show the recipes.
default:
    @just --list

# Compile the standalone binary (optimized).
build:
    nim c -d:release -d:ssl --hints:off -o:freeqsay src/freeqsay.nim

# Fully static binary → ./freeqsay-static. No glibc, no dlopen'd OpenSSL, so it
# runs on any Linux. tools/nimstatic is a DotSlash file: the first run fetches
# the pinned nimstatic build, verifies its hash and caches it.
static:
    ./tools/nimstatic src/freeqsay.nim -o freeqsay-static -- -d:ssl

# Run the test suite.
test:
    nim c -d:ssl --hints:off -r tests/test_avatar.nim

# Run from source, without an optimized build: `just run jay.bsky.team hello`.
run *args:
    nim r -d:ssl --hints:off src/freeqsay.nim {{args}}

# Screenshot the output, gapless (termshot-tight sets lineSpacing 1.0):
# `just shot jay.bsky.team hello`. Writes freeqsay.png.
shot *args:
    termshot -c -C 80 -f freeqsay.png -- nim r -d:ssl --hints:off src/freeqsay.nim {{args}}

# Remove build output and caches.
clean:
    rm -rf freeqsay tests/test_avatar nimcache tests/nimcache